返回列表 发帖

[技术文章] 用批处理文件自动备份文件及文件夹,并自动删除N天前的文件

下是备份的批处理,添加到"计划任务"中,设定时间自动运行,代码如下:
  1. @echo off
  2. rem 格式化日期
  3. rem date出来的日期是"2006-02-22 星期三",不能直接拿来使用,所以应该先格式化一下
  4. rem 变成我们想要的。date:~0,4的意思是从0开始截取4个字符
  5. set d=%date:~0,4%%date:~5,2%%date:~8,2%
  6. rem 设定压缩程序路径,这里用的是WINRAR的rar.exe进行打包的
  7. set path=C:\Program Files\WinRAR
  8. rem 设定要备份的目录
  9. set srcDir=D:\databasc
  10. rem 设定备份文件所在目录
  11. set dstDir=E:\temp\backup
  12. rem 设定备份文件的前缀,目前为temp,前缀为backup
  13. set webPrefix=
  14. rem 如果文件不存在,开始备份
  15. if not exist %dstDir%%webPrefix%%d%.rar start Rar a -r %dstDir%%webPrefix%%d%.rar %srcDir%
  16. @echo on
复制代码
以下是删除N天前备份文件的批处理,注:在windows2003下,如XP下因为没有forfiles.exe,未测试拷贝2003的文件到XP的system32目录
删除在C盘backup目录下最后修改日期在10天前的文件
=================================================================================
forfiles /p "c:\backup" /d -10 /c "cmd /c echo deleting @file ... && del /f @path"
=================================================================================
以下是复制某天前文件到其它位置的批处理
要把在C盘根目录下最后修改日期大于或等于2007年7月1日的文件复制到D盘根目录下
=================================================================================
forfiles /p "c:\" /d "2007-7-1" /c "cmd /c copy @path d:\"
Windows Server 2003内置的命令行文件,适合于XP以上系统
示例:
forfiles /m *.bkf /d -28 /c "cmd /c del @file /f"
删除当前目录下28天以前的扩展名为bkf文件(以当前系统时间为基准)
forfiles 自动删除7天前文件 delete
2008-09-12 15:01
用forfiles.exe试试。
forfiles /p "d:\test" /s /m *.* /d -7 /c "cmd /c del @path"
做成批处理文件,bat文件与forfiles.exe同一目录下,建一个bat文件的快捷方式在启动。
d:\test换成你要的目录路径。日期是指修改的日期。
附上forfiles.exe及帮助。
删除所有的空目录(以删除d:\test目录下为例)
dir /ad/b/s d:\test\ |sort /r >d:\kill.txt
For /f "tokens=*" %%i in (d:\kill.txt) DO rd "%%i"
del d:\kill.txt
把以下复制到bat文件中。
@echo off
forfiles /p "d:\test" /s /m *.* /d -7 /c "cmd /c del @path"
dir /ad/b/s d:\test\ |sort /r >d:\kill.txt
For /f "tokens=*" %%i in (d:\kill.txt) DO rd "%%i"
del d:\kill.txt
先删过期文件,再删所有的空目录
如果操作系统是 Windows Server 2003 那就好办了,因为它有一个forfiles命令能够查找满足指定条件的文件,下面是这个命令的用法。
forfiles /p <目标目录名> /d <天数> /c <执行的命令>
看看列出的三个参数都有什么用处:
/p 指定了要在哪个目录里查找文件,默认是当前工作目录。
/d 指定一个日期或天数,用于比较文件的最后修改日期是否符合条件。
/c 对每个找到的文件执行的命令。
例1.要把在C盘根目录下最后修改日期大于或等于2007年7月1日的文件复制到D盘根目录下:
forfiles /p "c:\" /d "2007-7-1" /c "cmd /c copy @path d:\"
例2.删除在C盘backup目录下最后修改日期在10天前的文件:
forfiles /p "c:\backup" /d -10 /c "cmd /c echo deleting @file ... && del /f @path"
先看删除文件的代码
forfiles /p 包含要删除文件的完整路径(如:F:\Logfiles) /m *.log -d -7 /c "cmd /c del /f @path"
解释一下相关参数及命令
/p <Path> : 指定开始搜索文件的位置,如果不指定则默认为当前目录。
/m <SearchMask> : 文件查找所使用的通配符如代码中的"*.log"则为所有日志文件,当然也可以指定诸如"manmee_*.log"这样以manmee开头的所有日志文件。如果不指定此参数则默认为"*.*"。
/d [{+|-}][{<Date>|<Days>}] : 指定想选择文件的最后修改时间,上文中用了 "/d -7" 表示所有以当天为基础,7天以前的文件。当然这里还可以指定具体时间,例如:"/d -08/18/2009"这样所有早于2009年8月18日的文件。注意指定的时间必须是"MM/DD/YYYY"的格式。
/c 对所有文件以此执行指定的命令,命令体须在双引号(")内,默认是"cmd /c echo @file"。上文中用到的是"cmd /c del /f @path"删除指定文件。(这里的@file 和 @path 为变量,下文中将解释。)
下面说一下上文中用到的参数:
@PATH : 表示文件的完整的路径。
@File : 表示文件名称。
其他参数的详细介绍点击这里。
接下来我们看看删除文件夹的操作,如果你看了上面的介绍,相信这命令你一看就能看懂。
forfiles /p 包含文件夹的路径(如:F:\) /m 文件夹名称(如:LogFiles) -d 0 /c "cmd /c if @ISDIR == true rd /s/q @path"
注意这里的"包含文件夹的路径"不能包含要删除的文件夹,如以上代码所表示的就是,在F盘中查找名为LogFiles的文件或文件夹(不能指定查找文件夹,不过在删除时我们做了判断)。
还有就是这里出现了一个新的参数"@ISDIR"他用于判断当前文件类型是否是"文件夹类型",如果是则为true否则为false。
相信到这大家就明白了,最后再将代码保存为批处理文件,然后加入计划任务定期执行即可。
看了上面的例子,觉得在 Windows Server 2003 下面要删除老文件很简单吧。
但如果操作系统是 Windows 2000/XP 就比较麻烦,因为它们没有forfiles命令,只能靠自己写批处理来实现了。
下面是批处理文件内容:
  1. @echo off
  2. rem ******************************
  3. rem * 按时间删除文件目录的批处理 *
  4. rem ******************************
  5. rem 设置临时目录的路径
  6. set tempDir=%tmp%\remove_%date:~0,10%
  7. if not exist %tempDir% md %tempDir%
  8. rem 设置处理日期的脚本文件的路径
  9. set scriptFile=%tempDir%\get_date.vbs
  10. rem 获得要保留的天数
  11. set days=%~1
  12. if "%days%" == "" goto printUsage
  13. rem 获得目标目录的路径
  14. set dirPath=%~2
  15. if "%dirPath%" == "" set dirPath=.
  16. rem 获得要操作的文件形式
  17. set fileSpec=%~3
  18. if "%fileSpec%" == "" set fileSpec=*.*
  19. rem 生成计算日期的脚本文件并获得删除的截止日期
  20. echo d=date()-%1 > %scriptFile%
  21. echo s=right("0000" ^& year(d),4) ^& "-" ^& right("00" ^& month(d),2) ^& "-" ^& right("00" ^& day(d),2) >> %scriptFile%
  22. echo wscript.echo s >> %scriptFile%
  23. for /f %%i in ('cscript /nologo %scriptFile%') do set lastDate=%%i
  24. rem 处理目标目录里的每个对象
  25. for /f "tokens=1,2,3* delims=<> " %%i in ('dir "%dirPath%\%fileSpec%" /a /-c /tc') do call :proc "%%i" "%%j" "%%k" "%%l"
  26. goto :done
  27. rem 处理目标目录里对象的过程
  28. :proc
  29. rem 获得对象的创建日期并判断是否为有效格式
  30. set fileDate=%~1
  31. echo %fileDate% | findstr "[0-9][0-9][0-9][0-9]-[0-9][0-9]-[0-9][0-9]" > nul
  32. if errorlevel 1 goto end
  33. rem 获得对象的类型
  34. set fileType=%~3
  35. if "%fileType%" == "" goto end
  36. rem 获得对象的名称
  37. set fileName=%~4
  38. if "%fileName%" == "" goto end
  39. if "%fileName%" == "." goto end
  40. if "%fileName%" == ".." goto end
  41. if "%fileName%" == "字节" goto end
  42. if "%fileName%" == "可用字节" goto end
  43. rem 判断对象日期是否小于或等于删除的截止日期
  44. if "%fileDate:~0,10%" leq "%lastDate%" (
  45. echo deleting "%fileName%" ...
  46. if "%fileType%" == "DIR" ( rd /s /q "%dirPath%\%fileName%" ) else ( del /q /f "%dirPath%\%fileName%" )
  47. )
  48. goto end
  49. :error
  50. echo An error occurred during backuping.
  51. :done
  52. rd /s /q %tempDir%
  53. goto end
  54. :printUsage
  55. echo Usage: %0 ^<Days^> [Work directory] [Target file specification (can include wildcards)]
  56. goto end
  57. :end
复制代码
主要是利用Windows的脚本功能来计算要删除文件的截止日期,然后for加dir命令来提取文件的日期进行判断。
关于forfiles和for的详细信息,可以在Windows的帮助与支持中找到。
欢迎光临:逐梦论坛

返回列表

Powered by Discuz! 7.2   论坛QQ群:逐梦论坛群

© 2001-2021 Comsenz Inc. 鲁公网安备 37120302000001号